UTF-8
// Ex:InputFormコマンドで選択した画像を表示

:Start {
 //log open: dir=Dir.Desktop file="debugMacro.txt";
 //debug: true;
 
 strl[11]=Dir.Desktop;  strl[11]+="\\てすと.txt";
 file delete: file=strl[11];
 
 // inp1.typeのパラメータ作成
 str["type"]="@FileSelect;";  str["type"]+=Dir.MyPic;
 str["type"]+="☊JPEG画像;jpg,jpeg,jpe";
 str["type"]+="☊GIF画像;gif";
 str["type"]+="☊すべて;*";
 
 Ex:InputForm: inp1="!画像選択" outfile=strl[11] message="選択した画像を Ex:ShowRSSコマンド で表示します。" inp1.type=str["type"] helpPage="{{GTMAIL_HOME}}\\Help\\fileDownloadMacroExInputForm.html" inp2="表示しますか？" inp2.value="SO☊Yes;;No";
 Ex:InputForm.Wait: waitSec=30 outfile=strl[11] O:result=strl["rslt"];
 if (strl["rslt"].StartsWith{"OK:"} == "false") {
   put: value="キャンセルまたはエラーです。\r\n" strl["rslt"];
   end:
   }
 
 // inp1.typeで @FileSelect を指定しているので、str["1.value"] 
 // が既存ファイルかどうかの次のチェックは省略できます。
 // 
 // if (str["1.value"].isFile == "false") {
 //   put: value="ファイル " str["1.value"] " がありません。";
 //   end:
 //   }
 
 if (str["2.value"].Equals{"No"} == "true") {
   put: value=str["1.value"] "が選択されました。";
   end:
   }
 
 Ex:ShowRSS: file=str["1.value"];
 put: value=str["1.value"] "を表示しました。";
 end:
 }