CWS(ZLIB圧縮されたswfファイル) を FWS(非圧縮のswfファイル) に変換する (Ex:Decompressコマンドを使ったAdobe flashファイルの形式変換) - ダウンロードマクロ・コマンド (Download Macro Command) - PROSERPINE (プロセルピナ)

				プロセルピナ
Top	Internet Mail	Private Proxy	Capture Device		Download	Config and Words	Online Help	Online Home

[BACK]

☞ Top > FileDownload > Macro > Ex: Command > Decompress > Sample (CWS→FWS)

CWS(ZLIB圧縮されたswfファイル) を FWS(非圧縮のswfファイル) に変換
(Ex:Decompressコマンド)

Macro Top | Variables | Constants | Commands | Ex-Commands

概要

Ex:Decompressコマンドで、ZLIB圧縮されたオブジェクトを非圧縮の状態に展開(解凍)する例として、 Adobeの Flashファイル(swfファイル) を扱う例を示します。

Flashファイルのうち、Magic Word(ファイル先頭の３バイト)が CWS の場合、ファイルヘッダ以降の部分が ZLIB圧縮されています。
このZLIB圧縮部分を Ex:Decompressコマンドで展開し、非圧縮のswfファイル(Magic Wordが FWS) に変換します。

手順は、ヘッダ(ファイル先頭の8バイト)のうち、ヘッダ先頭の CWS の３バイトを FWS に変更し、そのヘッダ以降に非圧縮にしたデータを追加するだけです。
8バイトのヘッダのうち後半の4バイトはヘッダを含めたトータルのファイルサイズが格納されていますが、これはCWSファイルの場合でも展開後のサイズで設定されています。
よって、ファイルヘッダのうち、書き換えるのは先頭のMagic Wordの部分だけです (CWS → FWS)。

CWS→FWS変換

CWSファイルをFWSに変換する具体的なマクロを示します。
このマクロはパラメータ(input[0]) で CWSファイル(データ部がZLIB圧縮さたswfファイル) を受け取ります。

UTF-8
:Sample {
 str["src"]=input[0]
 
 read open: file=str["src"] enc="bin"
 read bin: O:bin=bin["Header"] rCount=8
 read close:
 if (bin["Header"].Length != 8) {
   put: "NG: ファイル先頭の８バイトが読めません。 Length=" bin["Header"].Length
   put: "file=" str["src"]
   end:
   }
 
 strl[10]=bin["Header"].Substring0(3) // 先頭３バイトを文字列に変換
 if (strl[10] == "FWS") {
   put: "NG: 圧縮されていないswfファイル(FWS) です。\r\n" str["src"]
   end:
   }
 if (strl[10] != "CWS") {
   put: "NG: 圧縮されたswfではありません。\r\n" str["src"]
   end:
   }
 
 Ex:Decompress: file=str["src"] skip=8 type="zlib" dest.dir=Dir.Work dest.MidName="aaa" O:destfile=str["解凍"] O:result=str[11]
 // 
 // Ex:Decompressコマンドで、ファイルの８バイト目以降のZLIB圧縮を展開(解凍)し、
 // ワークフォルダ(Dir.Work)に展開された内容のファイルを作成
 // 
 if (str[11].StartsWith{"OK:"} != "true") {
   put: "NG: Zlib圧縮の展開(解凍)ができません。\r\n"
   put: str[11]
   end:
   }
 
 binl[10]=bin["Header"].Substring(3) // ヘッダの３バイト目以降を取得
 if (binl[10].Length != 5) {
   put: "Error!"
   end:
   }
 
 str["NewName"]="非圧縮-" str["src"].FilenameShort
 write open: dir=Dir.DeskTop file=str["NewName"] enc="bin"
 write: w="FWS"
 write: w=binl[10]
 readBinfile:  file=str["解凍"] O:data=binl[20]
 write: w=binl[20] //非圧縮の内容を書き込む
 write close: O:name=str["非圧縮swf"]
 
 file delete: file=str["解凍"]
 //一時ファイルの削除
 
 put: "非圧縮SWFファイルに変換しました。\r\n" str["非圧縮swf"]
 
 end:
 }

上記例をファイルにそのまま保存し、実際に動作させて確認することができます。
例えばパラメータに
C:\Documents and Settings\MyName\Work\cws_sample.swf
というswfファイルを渡してマクロを起動すると、
デスクトップに 非圧縮-cws_sample.swf という非圧縮swfファイルを作成します。

Ex:Decompressコマンドで圧縮を解除するのはデータ部のみなので、
skip=8
を指定して swfファイルのヘッダ部をスキップしています。
ZLIB圧縮を展開するので
type="zlib"
を指定します。
圧縮解除された内容を格納するファイルのファイル名は、パラメータ O:destfile= で指定した文字列変数 str["解凍"] に設定されます。
このファイルの内容は Ex:readBinfileコマンドでバイナリ変数 binl[20] に読み取って、新しく作成するswfファイルに書き込んでいます。

[BACK]

プロセルピナ